Встроенные функции

• Алгебраические функции
• Функция DBINFO
• Экспоненциальные и логарифмические функции
• Функция HEX
• Функции длины строки
• Функции над временем
• Тригонометрические функции
• Строковые функции

<встроенная функция> ::=

<алгебраическая функция>
| <функция DBINFO>
| <экспоненциальная или логарифмическая функция>
| <функция HEX>
| <функция длины строки>
| <функция над временем>
| <тригонометрическая функция>
| <строковая функция>

Алгебраические функции

<алгебраическая функция> ::=

ABS (<числовое выражение>)
| MOD (<делимое>, <делитель>)
| POW (<основание>, <показатель степени>)
| ROOT (<подкоренное выражение> [, <показатель степени>])
| ROUND (<выражение> [, <порядок>])
| SQRT (<подкоренное выражение>)
| TRUNC (<выражение> [, <порядок>])

<делимое> ::=

<числовое выражение>

<делитель> ::=

<числовое выражение>

<основание> ::=

<числовое выражение>

<показатель степени> ::=

<числовое выражение>

<подкоренное выражение> ::=

<числовое выражение>

<порядок> ::=

<целочисленное выражение>

Примечание

Числовое выражение -- выражение, значением которого является вещественное число.
Целочисленное выражение -- выражение, значением которого является целое число.

Функция DBINFO

<функция DBINFO> ::=

DBINFO (<указатель информации>)

<указатель информации> ::=

'DBSPACE' , <указатель табличного пространства>
| 'sqlca.sqlerrd1'
| 'sqlca.sqlerrd2' | 'sessionid'
| 'dbhostname'
| 'version' , <спецификатор версии>

<указатель табличного пространства> ::=

<целочисленное выражение>

<спецификатор версии> ::=

'server-type' | 'major' | 'minor' | 'os' | 'level' | 'full'

Экспоненциальные и логарифмические функции

<экспоненциальная или логарифмическая функция> ::=

EXP (<числовое выражение>)
| LOGN (<числовое выражение>)
| LOG10 (<числовое выражение>)

Функция HEX

<функция HEX> ::=

HEX (<целочисленное выражение>)

Функции длины строки

<функция длины строки> ::=

<имя функции длины строки> (<аргумент функции длины строки>)

<имя функции длины строки> ::=

LENGTH | CHAR_LENGTH | CHARACTER_LENGTH | OCTET_LENGTH

<аргумент функции длины строки> ::=

<строка в кавычках>
| <имя переменной>
| [<уточнение имени столбца>.]<имя столбца>

Функции над временем

<функция над временем> ::=

DATE (<выражение типа не-DATE>)
| <элемент даты> (<выражение типа даты и времени>)
| EXTEND (<выражение типа даты и времени>
  [, <уточнение полей даты и времени>])
| MDY (<месяц>, <день>, <год>)
| TO_CHAR (<исходная дата> [, <строка формата>])
| TO_DATE (<символьное выражение> [, <строка формата>])

<элемент даты> ::=

DAY | MONTH | WEEKDAY | YEAR

<месяц> ::=

<целочисленное выражение>

<день> ::=

<целочисленное выражение>

<год> ::=

<целочисленное выражение>

<исходная дата> ::=

<выражение типа даты и времени>

<строка формата> ::=

<символьное выражение>

Примечание

Выражение типа даты и времени -- выражение, возвращающее значение типа даты или даты и времени.
Выражение типа не-DATE -- выражение, возвращающее значение типа DATETIME, символьное или целочисленное.
Символьное выражение -- выражение, возвращающее символьное значение.

Тригонометрические функции

<тригонометрическая функция> ::=

<прямая тригонометрическая функция> (<числовое выражение>)
| <обратная тригонометрическая функция> (<числовое выражение>)
| ATAN2 (<числовое выражение>, <числовое выражение>)

<прямая тригонометрическая функция> ::=

SIN | COS | TAN

<обратная тригонометрическая функция> ::=

ASIN | ACOS | ATAN

Строковые функции

<строковая функция> ::=

<функция TRIM>
| <функция SUBSTRING>
| <функция SUBSTR>
| <функция REPLACE>
| <функция LPAD>
| <функция RPAD>
| <функция преобразования регистра>

<функция TRIM> ::=

TRIM ([[<уточнение позиции>] <односимвольное выражение> FROM]
  <символьное выражение>)

<уточнение позиции> ::=

LEADING | TRAILING | BOTH

<функция SUBSTRING> ::=

SUBSTRING (<исходная строка> FROM<начальная позиция>
  [FOR <длина подстроки>])

<исходная строка> ::=

<выражение>

<начальная позиция> ::=

<целочисленное выражение>

<длина подстроки> ::=

<целочисленное выражение>

<функция SUBSTR> ::=

SUBSTR (<исходная строка>, <начальная позиция> [, <длина подстроки>])

<функция REPLACE> ::=

REPLACE (<исходная строка>, <старая строка> [, <новая строка>])

<старая строка> ::=

<выражение>

<новая строка> ::=

<выражение>

<функция LPAD> ::=

LPAD (<исходная строка>, <длина подстроки> [, <строка дополнения>])

<строка дополнения> ::=

<выражение>

<функция RPAD> ::=

RPAD (<исходная строка>, <длина подстроки> [, <строка дополнения>])

<функция преобразования регистра> ::=

<имя функции регистра> (<символьное выражение>)

<имя функции регистра> ::=

UPPER | LOWER | INITCAP

Примечание

Односимвольное выражение -- символьное выражение, имеющее значение одного символа или значение NULL.